;note also test for dexti (decoder immediate extend (used for est))	
	
;*********************************************************************	
; includes
;*********************************************************************	

	.incdir	"F:\git\goldmomo_endlos\assembler_files\ucore\"
	.include "include\ucore_ctrl.i"

;*********************************************************************	
; sd header is placed here
;*********************************************************************	

	.include "boot_level_sdHeader.s"

;*********************************************************************
;* start at address 32 here
;*********************************************************************

	.def	frame		$d0000000
	.def	hcoreStartPc	$d0100000

start	
	cli
	
	;setup video (360x225)
	
	gpci	r7,2		;next 4 + X
	br	setupVideo
	nop			;delay slot
	nop			;delay slot
	nop			;delay slot
	nop			;delay slot
	
	;clear frame
	
	movei	r1,0		
	dexti	$27
	movei	r0,$8c		;360*225/8 -1
	gpci	r7,2
	br	efill8
	dexti	>>>frame	;delay slot
	movei	r3,>>frame     	;delay slot
	dexti	>frame         	;delay slot
	movei	r2,frame       	;delay slot
	
	;copy hcore programm
	
	dexti	>hcoreProgram
	movei	r1,hcoreProgram
	gpci	r7,2
	br	copyToHcore
	dexti	>>>hcoreStartPc		;delay slot
	movei	r3,>>hcoreStartPc     	;delay slot
	dexti	>hcoreStartPc         	;delay slot
	movei	r2,hcoreStartPc       	;delay slot
	
	;wait
	

	dexti	$ff
	movei	r0,$ff
	nop

l1	subi	r0,1
	brts	l1
	nop			;delay slot
	nop			;delay slot
	nop			;delay slot
	nop			;delay slot
	
	
	;release hcore reset
	
	dexti	>UcHcoreCtrl
	movei	r0,UcHcoreCtrl
	movei	r1,0		;rest to 0
	nop
	st	r0,r1
	
end	br	end	
	nop			;delay slot
	nop			;delay slot
	nop			;delay slot
	nop			;delay slot
	
;******************************
;*
;* efill8
;*
;* r0	 = count - 1
;* r1 	 = value to fill
;* r3:r2 = dest address
;*
	
efill8	
	nop
	
clearFBLoop
	esadr	r3,r2	;destination
	est	r1,0
	est	r1,1
	est	r1,2
	est	r1,3
	est	r1,4
	est	r1,5
	subi	r0,1
	brts	clearFBLoop
	addi	r2,8            ;delay slot
	addtqi	r3,r3,0         ;delay slot	
	est	r1,6		;delay slot
	est	r1,7            ;delay slot

	jmpi	r7,0
	nop		;delay slot
	nop		;delay slot	
	nop		;delay slot
	nop		;delay slot

;******************************
;*
;* copyToHcore
;*
;* r1 	 = source address
;* r3:r2 = dest address
;*
	
copyToHcore	

	dexti	$ff
	movei	r6,$ff 
	esadr	r3,r2

copyToHcoreLoop

	rqldi	r1,0	;high
	rqldi	r1,1	;low
	addi	r1,2	;next word
	ld	r4
	ld	r5
	
	addi	r2,2
	addtqi	r3,r3,0

	cmpeq	r4,r6
	brtc	copyToHcoreLoop
	est	r4,0		;delay slot
	est	r5,1		;delay slot	
	nop			;delay slot
	esadr	r3,r2		;delay slot

	jmpi	r7,0
	nop		;delay slot
	nop		;delay slot	
	nop		;delay slot
	nop		;delay slot
	
;******************************
;*
;* setupVideo
;*

setupVideo

	
	movei	r0,videoDefault		;source
	movei	r1,UcTimer2Ctrl		;dest-1
	moveih	r0,>videoDefault
	moveih	r1,>UcTimer2Ctrl			
	movei	r2,26			;27-1
	
setupVideoLoop

	rqldi	r0,0
	addi	r0,1
	addi	r1,1
	ld	r3
	subi	r2,1
	brts	setupVideoLoop
	st	r1,r3	;delay slot
	nop		;delay slot
	nop		;delay slot
	nop		;delay slot
		
	jmpi	r7,0
	nop		;delay slot
	nop		;delay slot
	nop		;delay slot
	nop		;delay slot	
	
;*********************************************************************
;* data
;*********************************************************************
	
videoDefault		;AD NAME									
	
	word	$0001	;10 VIDEO_ON					1				
	word	$0097	;11 HSYNC (D = 11 .. 0)				152-1				
	word	$017f	;12 HSTART (D = 11 .. 0)			384-1				
	word	$017d	;13 HMEMSTART (D = 11 .. 0)			382-1				
	word	$071f	;14 HSTOP (D = 11 .. 0)				1824-1				
	word	$076f	;15 HTOTAL (D = 11 .. 0)			1904-1				
	word	$0002	;16 VSYNC (D = 10 .. 0)				3-1				
	word	$001e	;17 VSTART (D = 10 .. 0)			31-1				
	word	$03a2	;18 VSTOP  (D = 10 .. 0)			931-1				
	word	$03a3	;19 VTOTAL  (D = 10 .. 0)			932-1				
	word	$0000	;1a LC ADDER LOW				$0000				
	word	$0040	;1b LC ADDER HIGH				$0080				
	word	$0000	;1c LC ADDER LATCH				X				
	word	$0000	;1d LC START (10 .. 0) Pixeloffset		$0000				
	word	$0000	;1e						X				
	word	$0000	;1f						X				
	word	$0008	;20 HLOADSTART 					8				
	word	$00bc	;21 HLOADSTOP					360+8				
	word	$001e	;22 VLOADSTART 					31-1				
	word	$03a2	;23 VLOADSTOP 					931-1				
	word	$0004	;24 VLOADNEXT					2				
	word	$0000	;25 MEM_STARTADR_store low			$0000				
	word	$d000	;26 MEM_STARTADR_store high			$f000				
	word	$0000	;27 MEM_LINEOFFSET_store low			$0000				
	word	$0000	;28 MEM_LINEOFFSET_store high			$0000				
	word	$0003	;29 MEM_MODE_store 				3	------rrrrggggbbbb----rrrrggggbbbb
	word	$0000	;2a LATCH MEM_STARTADR/LINEOFFSET/MODE		X	
	
	;
	
	.data	$ffff,$ffff
		
hcoreProgram

	.incdir		"F:\git\goldmomo_endlos\assembler_files\ucore\hcore"
	.asmhcore 	"test5.s"
		
	.data	$ffff,$ffff
	